bat 脚本的常用特殊符号

1、@??命令行回显屏蔽符
2、%??批处理变量引导符
3、>???重定向符
4、>>??重定向符
5、<、>&、<& 重定向符
6、|??命令管道符
7、^??转义字符
8、&??组合命令
9、&& 组合命令
10、||??组合命令
11、""??字符串界定符
12、, 逗号
13、; 分号
14、() 括号
15、! 感叹号
16、批处理中可能会见到的其它特殊标记符: （略）
????????CR(0D) 命令行结束符?
????????Escape(1B) ANSI转义字符引导符?
????????Space(20) 常用的参数界定符?
????????Tab(09) ; = 不常用的参数界定符?
????????+ COPY命令文件连接符?
????????* ? 文件通配符?
????????/ 参数开关引导符?
????????: 批处理标签引导符?

1、@??命令行回显屏蔽符

这个字符在批处理中的意思是关闭当前行的回显。
ECHO OFF可以关闭掉整个批处理命令的回显，但不能关掉ECHO OFF这个命令，现在我们在ECHO OFF这个命令前加个@，就可以达到所有命令均不回显的要求

2、%??批处理变量引导符

这个百分号严格来说是算不上命令的，它只是批处理中的参数而已（多个%一起使用的情况除外，以后还将详细介绍）。
引用变量用%var%，调用程序外部参数用%1至%9等等
%0??%1??%2??%3??%4??%5??%6??%7??%8??%9??%*为命令行传递给批处理的参数
%0 批处理文件本身，包括完整的路径和扩展名
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的所有参数
参数%0具有特殊的功能，可以调用批处理自身，以达到批处理本身循环的目的，也可以复制文件自身等等。
例：最简单的复制文件自身的方法
copy %0 d:\wind.bat
小技巧：添加行内注释
%注释内容%（可以用作行内注释，不能出现重定向符号和管道符号）
为什么这样呢？此时“注释内容”其实被当作变量，其值是空的，故只起注释作用，不过这种用法容易出现语法错误，一般不用。

3、>? ?重定向符

输出重定向命令
DOS的标准输入输出通常是在标准设备键盘和显示器上进行的，利用重定向,可以方便地将输入输出改向磁盘文件或其它设备。其中:?
1.大于号“>”将命令发送到文件或设备，例如打印机>prn。使用大于号“>”时，有些命令输出(例如错误消息)不能重定向。
2.双大于号“>>”将命令输出添加到文件结尾而不删除文件中已有的信息。
3.小于号“<”从文件而不是键盘上获取命令所需的输入。
4.>&符号将输出从一个默认I/O流(stdout,stdin,stderr)重新定向到另一个默认I/O流。
例如，command >output_file 2>&1将处理command过程中的所有错误信息从屏幕重定向到标准文件输出中。标准输出的数值如下所示：
命令重定向的标准句柄

这个字符的意思是传递并且覆盖，他所起的作用是将运行的结果传递到后面的范围（后边可以是文件，也可以是默认的系统控制台）
在NT系列命令行中，重定向的作用范围由整个命令行转变为单个命令语句，受到了命令分隔符&,&&,||和语句块的制约限制。
比如：
使用命令：echo hello >1.txt将建立文件1.txt，内容为”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt将建立文件1.txt，内容为”hello“（注意行尾没有空格）

4、>>??重定向符

输出重定向命令
这个符号的作用和>有点类似，但他们的区别是>>是传递并在文件的末尾追加，而>是覆盖
用法同上
同样拿1.txt做例子
使用命令：
echo hello > 1.txt
echo world >>1.txt
这时候1.txt 内容如下:
hello
world

5、<、>&、<& 重定向符

这三个命令也是管道命令，但它们一般不常用，你只需要知道一下就ok了，当然如果想仔细研究的话，可以自己查一下资料。(本人已查过，网上也查不到相关资料)
<，输入重定向命令，从文件中读入命令输入，而不是从键盘中读入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
这样就可以不等待输入直接修改当前日期
>&，将一个句柄的输出写入到另一个句柄的输入中。
<&，刚好和>&相反，从一个句柄读取输入并将其写入到另一个句柄输出中。
常用句柄：0、1、2，未定义句柄：3—9
1>nul 表示禁止输出正确的信息
2>nul 表示禁止输出错误信息。
其中的1与2都是代表某个数据流输入输出的地址（NT CMD 称之为句柄，MSDOS称之为设备）。
句柄0：标准输入stdin，键盘输入
句柄1：标准输出stdout，输出到命令提示符窗口（console，代码为CON）
句柄2：标准错误stderr，输出到命令提示符窗口（console，代码为CON）
其中的stdin可被<重定向，stdout可被>、>>重定向。
我们已经知道读取文本中的内容可以用for命令，但如果只需要读取第一行用for命令就有点麻烦。简单的办法如下:
@echo off
set /p str=<%0
echo %str%
pause
运行显示批处理文件自身的第一行：@echo off

6、|??命令管道符

格式：第一条命令 | 第二条命令 [| 第三条命令...]
将第一条命令的结果作为第二条命令的参数来使用，记得在unix中这种方式很常见。
例如：
dir c:\|find "txt"
以上命令是：查找C：\所有，并发现TXT字符串。
FIND的功能请用 FIND /? 自行查看
在不使format的自动格式化参数时，我是这样来自动格式化A盘的
echo y|format a: /s /q /v:system
用过format的都知道，再格盘时要输入y来确认是否格盘，这个命令前加上echo y并用|字符来将echo y的结果传给format命令
从而达到自动输入y的目的
（这条命令有危害性，测试时请慎重）

7、^??转义字符

^是对特殊符号<,>,&的前导字符，在命令中他将以上3个符号的特殊功能去掉，仅仅只把他们当成符号而不使用他们的特殊意义。
比如
echo test ^>1.txt
结果则是：test > 1.txt
他没有追加在1.txt里，呵呵。只是显示了出来
另外，此转义字符还可以用作续行符号。
举个简单的例子：
@echo off
echo 英雄^
是^
好^
男人
pause
不用多说，自己试一下就明白了。
为什么转义字符放在行尾可以起到续行符的作用呢？原因很简单，因为每行末尾还有一个看不见的符号，即回车符，转义字符位于行尾时就让回车符失效了，从而起到了续行的作用。

8、& 组合命令

语法：第一条命令 & 第二条命令 [& 第三条命令...]
&、&&、||为组合命令，顾名思义，就是可以把多个命令组合起来当一个命令来执行。这在批处理脚本里是允许的，而且用的非常广泛。因为批处理认行不认命令数目。
这个符号允许在一行中使用2个以上不同的命令，当第一个命令执行失败了，也不影响后边的命令执行。
这里&两边的命令是顺序执行的，从前往后执行。
比如：
dir z:\ & dir y:\ & dir c:\
以上命令会连续显示z,y,c盘的内容，不理会该盘是否存在

9、&& 组合命令

语法：第一条命令 && 第二条命令 [&& 第三条命令...]
用这种方法可以同时执行多条命令，当碰到执行出错的命令后将不执行后面的命令，如果一直没有出错则一直执行完所有命令
这个命令和上边的类似，但区别是，第一个命令失败时，后边的命令也不会执行
dir z:\ && dir y:\ && dir c:\

10、||??组合命令

语法：第一条命令 || 第二条命令 [|| 第三条命令...]
用这种方法可以同时执行多条命令，当一条命令失败后才执行第二条命令，当碰到执行正确的命令后将不执行后面的命令，如果没有出现正确的命令则一直执行完所有命令；
提示：组合命令和重定向命令一起使用必须注意优先级
管道命令的优先级高于重定向命令，重定向命令的优先级高于组合命令
问题：把C盘和D盘的文件和文件夹列出到a.txt文件中。看例：
dir c:\ && dir d:\ > a.txt
这 样执行后a.txt里只有D盘的信息！为什么？因为组合命令的优先级没有重定向命令的优先级高！所以这句在执行时将本行分成这两部分：dir c:\和dir d:\ > a.txt，而并不是如你想的这两部分：dir c:\ && dir d:\和> a.txt。要使用组合命令&&达到题目的要求，必须得这么写：
dir c:\ > a.txt && dir d:\ >> a.txt
这样，依据优先级高低，DOS将把这句话分成以下两部分：dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的几句的差别比较特殊，值得好好研究体会一下。
当然这里还可以利用&命令（自己想一下道理哦）：
dir c:\ > a.txt & dir d:\ >> a.txt
[这个也可以用 dir c:\;d:\ >>a.txt 来实现]

11、""??字符串界定符

双引号允许在字符串中包含空格，进入一个特殊目录可以用如下方法
cd "program files"
cd progra~1
cd pro*
以上三种方法都可以进入program files这个目录

12、, 逗号

逗号相当于空格，在某些情况下“,”可以用来当做空格使
比如
dir,c:\

13、; 分号

分号，当命令相同时，可以将不同目标用；来隔离，但执行效果不变，如执行过程中发生错误，则只返回错误报告，但程序仍会执行。（有人说不会继续执行，其实测试一下就知道了，只不过它的执行有个规则，请看下面的规则）
比如：
dir c:\;d:\;e:\;z:\
以上命令相当于
dir c:\
dir d:\
dir e:\
dir f:\
如果其中z盘不存在，运行显示：系统找不到指定的路径。然后终止命令的执行。
例：dir c:\;d:\;e:\1.txt
以上命令相当于
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在，但e盘存在，有错误提示，但命令仍会执行。
规则：(我是在操作系统是XP SP3,英文版下测试的)
1.如果目标路径不存在，则整个语句都不执行，例如dir c:\;c:\dfdfdf\a.txt，则根本不会执行，因为我没有c:\dfdfdf\这个目录；
2.如果路径存在，仅文件不存在，则会继续执行，并且提示文件不存在的错误，例如：dir c:\;c:\temp\a.txt，我的目录中有c:\temp\文件夹，但这个目录下面没有1.txt这个文件。

14、() 括号

小括号在批处理编程中有特殊的作用，左右括号必须成对使用，括号中可以包括多行命令，这些命令将被看成一个整体，视为一条命令行。
? ? 括号在for语句和if语句中常见，用来嵌套使用循环或条件语句，其实括号()也可以单独使用，请看例子。
例：
命令：echo 1 & echo 2 & echo 3
可以写成：
(
echo 1
echo 2
echo 3
)
上面两种写法效果一样，这两种写法都被视为是一条命令行。
注意：这种多条命令被视为一条命令行时，如果其中有变量，就涉及到变量延迟的问题。

15、! 感叹号

没啥说的，在变量延迟问题中，用来表示变量，即%var%应该表示为!var!，请看前面的setlocal命令介绍。

三、DOS循环：for命令详解

如果你有什么命令不懂,直接在CMD下面输入:
name /? 这样的格式来看系统给出的帮助文件,比如for /? 就会把FOR命令的帮助全部显示出来!

1，基本格式

FOR %%variable IN (set) DO command [command-parameters]
??%%variable??指定一个单一字母表示可替换的参数。
??(set)? ?? ?指定一个或一组文件。可以使用通配符。
??command? ? 指定对每个文件执行的命令。
??command-parameters 为特定命令指定参数或命令行开关。

在批处理程序中使用 FOR 命令时，指定变量请使用 %%variable
而不要用 %variable。变量名称是区分大小写的，所以 %i 不同于 %I

参数:FOR有4个参数 /d? ?/l? ?/r? ?/f? ?他们的作用我在下面用例子解释

?2，参数 /d

FOR /D %%variable IN (set) DO command [command-parameters]
含义：如果集中包含通配符，则指定与目录名匹配，而不与文件名匹配。
如果 Set (也就是我上面写的 "相关文件或命令") 包含通配符（* 和 ?），将对与 Set 相匹配的每个目录（而不是指定目录中的文件组）执行指定的 Command。
这个参数主要用于目录搜索,不会搜索文件,看这样的例子：

1. @echo off

2. for /d %%i in (c:\*) do echo %%i

3. pause

运行会把C盘根目录下的全部目录名字打印出来,而文件名字一个也不显示!
在来一个,比如我们要把当前路径下文件夹的名字只有1-3个字母的打出来：

1. @echo off

2. for /d %%i in (???) do echo %%i

3. pause

这样的话如果你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
这里解释下*号和?号的作用,*号表示任意N个字符,而?号只表示任意一个字符
知道作用了,给大家个思考题目：

1. @echo off

2. for /d %%i in (window?) do echo %%i

3. pause

保存到C盘下执行,会显示什么呢?自己看吧! 显示：windows
/D参数只能显示当前目录下的目录名字,这个大家要注意!

3，参数 /R

FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
含义：检查以 [drive:]path 为根的目录树，指向每个目录中的FOR 语句。如果在 /R 后没有指定目录，则使用当前目录。如果集仅为一个单点(.)字符，则枚举该目录树。
递归
上面我们知道,/D只能显示当前路径下的目录名字,那么现在这个/R也是和目录有关,他能干嘛呢?放心他比/D强大多了!
他可以把当前或者你指定路径下的文件名字全部读取,注意是文件名字,有什么用看例子!
注意2点：
? ? 1、set中的文件名如果含有通配符(？或*)，则列举/R参数指定的目录及其下面的所用子目录中与set相符合的所有文件，无相符文件的目录则不列举。
? ? 2、相反，如果set中为具体文件名，不含通配符，则枚举该目录树（即列举该目录及其下面的所有子目录），而不管set中的指定文件是否存在。这与前面所说的单点（.）枚举目录树是一个道理，单点代表当前目录，也可视为一个文件。
例：

1. @echo off

2. for /r c:\ %%i in (*.exe) do echo %%i

3. pause

咱们把这个BAT保存到D盘随便哪里然后执行,我会就会看到,他把C盘根目录,和每个目录的子目录下面全部的EXE文件都列出来了!!!!
例：

1. @echo off

2. for /r %%i in (*.exe) do @echo %%i

3. pause

运行本例发现枚举了c盘所有目录，为了只列举boot.ini存在的目录，可改成下面这样：

1. @echo off

2. for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i

3. pause

4、参数 /L

FOR /L %%variable IN (start,step,end) DO command [command-parameters]
含义：该集表示以增量形式从开始到结束的一个数字序列。因此，(1,1,5) 将产生序列 1 2 3 4 5，(5,-1,1) 将产生序列 (5 4 3 2 1)。
使用迭代变量设置起始值 (Start#)，然后逐步执行一组范围的值，直到该值超过所设置的终止值 (End#)。/L 将通过对 Start# 与 End# 进行比较来执行迭代变量。如果 Start# 小于 End#，就会执行该命令。如果迭代变量超过 End#，则命令解释程序退出此循环。还可以使用负的 Step# 以递减数值的方式逐步执行此范围内的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 则生成序列 (5 4 3 2 1)。
例子：

1. @echo off

2. for /l %%i in (1,1,5) do @echo %%i

3. pause

保存执行看效果,他会打印从1 2 3 4 5??这样5个数字
(1,1,5)这个参数也就是表示从1开始每次加1直到5终止!
等会晕,就打印个数字有P用...好的满足大家,看这个例子：

1. @echo off

2. for /l %%i in (1,1,5) do start cmd

3. pause

执行后是不是吓了一跳,怎么多了5个CMD窗口,呵呵!如果把那个 (1,1,5)改成 (1,1,65535)会有什么结果,我先告诉大家,会打开65535个CMD窗口....这么多你不死机算你强!
当然我们也可以把那个start cmd改成md %%i 这样就会建立指定个目录了!!!名字为1-65535

5、参数 /F

\迭代及文件解析
使用文件解析来处理命令输出、字符串及文件内容。使用迭代变量定义要检查的内容或字符串，并使用各种options选项进一步修改解析方式。使用options令牌选项指定哪些令牌应该作为迭代变量传递。请注意：在没有使用令牌选项时，/F 将只检查第一个令牌。
文件解析过程包括读取输出、字符串或文件内容，将其分成独立的文本行以及再将每行解析成零个或更多个令牌。然后通过设置为令牌的迭代变量值，调用 for 循环。默认情况下，/F 传递每个文件每一行的第一个空白分隔符号。跳过空行。
详细的帮助格式为：
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
含义：带引号的字符串"options"包括一个或多个指定不同解析选项的关键字。这些关键字为:
? ?? ???eol=c? ?? ?? ?? ? ? ? - 指一个行注释字符的结尾(就一个)(备注：默认以使用；号为行首字符的为注释行)
????????skip=n? ? ? ? ? ? ? ?- 指在文件开始时忽略的行数，(备注：最小为1，n可以大于文件的总行数，默认为1。)
? ?? ???delims=xxx? ? ? ? - 指分隔符集。这个替换了空格和跳格键的默认分隔符集。
? ?? ???tokens=x,y,m-n??- 指每行的哪一个符号被传递到每个迭代的 for 本身。这会导致额外变量名称的分配。m-n格式为一个范围。通过 nth 符号指定 mth。如果符号字符串中的最后一个字符星号，?那么额外的变量将在最后一个符号解析之后分配并接受行的保留文本。经测试，该参数最多只能区分31个字段。(备注：默认为1，则表示只显示分割后的第一列的内容，最大是31，超过最大则无法表示)
????????usebackq? ?? ???- 使用后引号（键盘上数字1左面的那个键`）。未使用参数usebackq时：file-set表示文件，但不能含有空格双引号表示字符串，即"string"单引号表示执行命令，即'command'使用参数usebackq时：file-set和"file-set"都表示文件当文件路径或名称中有空格时，就可以用双引号括起来单引号表示字符串，即'string'后引号表示命令执行，即`command`

例子：

1. @echo off

3. set pid=8080

4. for /f "tokens=2" %%a in ('tasklist ^| find /i "%pid%"') do (

5. if %%a==%pid% (goto f)

6. :f

7. echo 当前运行进程的pid=%pid%

8. taskkill /f /pid %pid%

9. call:startApp

10. exit

11. )

其实这里的tokens就是代步第几列的意思，可以表示区间列tokens=1-5, 也可以表示tokens=3单独列，后面的变量代变当前列的输出，依次后面的列，按照你字母的变量顺序进行输出，大家可以自己试试

For命令例1：

1. @echo off

2. rem 首先建立临时文件test.txt

3. echo ;注释行,这是临时文件,用完删除 >test.txt

4. echo 11段 12段 13段 14段 15段 16段 >>test.txt

5. echo 21段,22段,23段,24段,25段,26段 >>test.txt

6. echo 31段-32段-33段-34段-35段-36段 >>test.txt

7. FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k

8. Pause

9. Del test.txt

运行显示结果：
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
请按任意键继续. . .
为什么会这样?我来解释：
eol=;? ?? ?? ? 分号开头的行为注释行
tokens=1,3*? ? 将每行第1段,第3段和剩余字段分别赋予变量%%i，%%j，%%k
delims=,-? ???（减号后有一空格）以逗号减号和空格为分隔符，空格必须放在最后

For命令例2：

1. @echo off

2. FOR /F "eol= delims=" %%i in (test.txt) do echo %%i

3. Pause

For命令例3：

1. @echo off

2. FOR /F "delims=" %%i in ('net user') do @echo %%i

3. pause

四、FOR命令中的变量

FOR的变量全部列出来:
? ???~I? ? ? ? ? ? ?- 删除任何引号(")，扩展 %I
? ???%~fI? ? ? ? ?- 将 %I 扩展到一个完全合格的路径名
? ???%~dI? ?? ???- 仅将 %I 扩展到一个驱动器号
? ???%~pI? ?? ???- 仅将 %I 扩展到一个路径
? ???%~nI? ?? ???- 仅将 %I 扩展到一个文件名
? ???%~xI? ?? ???- 仅将 %I 扩展到一个文件扩展名
? ???%~sI? ?? ???- 扩展的路径只含有短名
? ???%~aI? ?? ???- 将 %I 扩展到文件的文件属性
? ???%~tI? ?? ???- 将 %I 扩展到文件的日期/时间
? ???%~zI? ?? ???- 将 %I 扩展到文件的大小
? ???%~$PATH:I? ?- 查找列在路径环境变量的目录，并将 %I 扩展到找到的第一个完全合格的名称。如果环境变量名未被定义，或者没有找到文件，此组合键会扩展到空字符串

我们可以看到每行都有一个大写字母"I",这个I其实就是我们在FOR带入的变量,我们FOR语句代入的变量名是什么,这里就写什么.
比如:FOR /F??%%z IN ('set') DO @echo %%z
这里我们代入的变量名是z那么我们就要把那个I改成z,例如%~fI改为%~fz
至于前面的%~p这样的内容就是语法了!

1、 ~I????????? - 删除任何引号(")，扩展 %I

作用：删除引号
例子:
首先建立临时文件temp.txt，内容如下

1. "1111

2. "2222"

3. 3333"

4. "4444"44

5. "55"55"55

1. @echo off

2. echo ^"1111>temp.txt

3. echo "2222">>temp.txt

4. echo 3333^">>temp.txt

5. echo "4444"44>>temp.txt

6. echo ^"55"55"55>>temp.txt

7. rem 上面建立临时文件，注意不成对的引号要加转义字符^，重定向符号前不要留空格

8. FOR /F "delims=" %%i IN (temp.txt) DO echo %%~i

9. pause

10. del temp.txt

执行后,我们看CMD的回显如下:
1111? ?? ?? ???#字符串前的引号被删除了
2222? ?? ?? ???#字符串首尾的引号都被删除了
3333"? ?? ?? ? #字符串前无引号，后面的引号保留
4444"44? ?? ???#字符串前面的引号删除了，而中间的引号保留
55"55"55? ?? ? #字符串前面的引号删除了，而中间的引号保留
请按任意键继续. . .
和之前temp.txt中的内容对比一下,我们会发现第1、2、5行的引号都消失了,这就是删除引号~i的作用了!
删除引号规则如下(BAT兄补充!)
1、若字符串首尾同时存在引号，则删除首尾的引号；
2、若字符串尾不存在引号，则删除字符串首的引号；
3、如果字符串中间存在引号，或者只在尾部存在引号，则不删除。

2、 %~fI? ?? ???- 将 %I 扩展到一个完全合格的路径名

例子:
把代码保存放在随便哪个地方,我这里就放桌面吧.

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi

2. pause

执行后显示内容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
当我把代码中的 %%~fi直接改成%%i

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i

2. pause

执行后就会显示以下内容：
test.bat
test.vbs
通过对比,我们很容易就看出没有路径了,这就是"将 %I 扩展到一个完全合格的路径名"的作用
也就是如果%i变量的内容是一个文件名的话,他就会把这个文件所在的绝对路径打印出来,而不只单单打印一个文件名!

3、 %~dI? ?? ???- 仅将 %I 扩展到一个驱动器号

例子:
代码如下,我还是放到桌面执行!

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di

2. pause

执行后我CMD里显示如下
C:
C:
我桌面就两个文件test.bat,test.vbs,%%~di作用是,如果变量%%i的内容是一个文件或者目录名,他就会把他这文件
或者目录所在的盘符号打印出来!

FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi pause

我就不打结果了,大家自己复制代码看结果吧,下面几个都是这么个用法,代码给出来,大家自己看结果吧!

5、 %~nI? ?? ???- 仅将 %I 扩展到一个文件名

只打印文件名字

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni

2. pause

6、 %~xI? ?? ???- 仅将 %I 扩展到一个文件扩展名

只打印文件的扩展名

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi

2. pause

7、 %~sI? ?? ???- 扩展的路径只含有短名

打印绝对短文件名

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si

2. pause

8、 %~aI? ?? ???- 将 %I 扩展到文件的文件属性

打印文件的属性

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai

2. pause

9、 %~tI? ?? ???- 将 %I 扩展到文件的日期/时间

打印文件建立的日期

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti

2. pause

10、 %~zI? ?? ???- 将 %I 扩展到文件的大小

打印文件的大小

1. FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi

2. pause

上面例子中的"delims=="可以改为"delims="，即不要分隔符

11、 %~$PATH:I - 查找列在路径环境变量的目录

并将 %I 扩展到找到的第一个完全合格的名称。如果环境变量名未被定义，或者没有找到文件，此组合键会扩展到空字符串
这是最后一个,和上面那些都不一样,我单独说说!
然后在把这些代码保存为批处理,放在桌面。

1. @echo off

2. FOR /F "delims=" %%i IN (“notepad.exe”) DO echo %%~$PATH:i

3. pause

龙卷风补充：上面代码显示结果为C:\WINDOWS\system32\notepad.exe
他的意思就在PATH变量里指定的路径里搜索notepad.exe文件，如果有notepad.exe则会把他所在绝对路径打印出来，没有就打印一个错误！

五、批处理中的变量

批处理中的变量,我把他分为两类,分别为"系统变量"和"自定义变量"

1，系统变量

他们的值由系统将其根据事先定义的条件自动赋值,也就是这些变量系统已经给他们定义了值,
不需要我们来给他赋值,我们只需要调用而以!??我把他们全部列出来!

1. %ALLUSERSPROFILE% 本地 返回“所有用户”配置文件的位置。

2. %APPDATA% 本地 返回默认情况下应用程序存储数据的位置。

3. %CD% 本地 返回当前目录字符串。

4. %CMDCMDLINE% 本地 返回用来启动当前的 Cmd.exe 的准确命令行。

5. %CMDEXTVERSION% 系统 返回当前的“命令处理程序扩展”的版本号。

6. %COMPUTERNAME% 系统 返回计算机的名称。

7. %COMSPEC% 系统 返回命令行解释器可执行程序的准确路径。

8. %DATE% 系统 返回当前日期。使用与 date /t 命令相同的格式。由 Cmd.exe 生成。有关date 命令的详细信息，请参阅 Date。

9. %ERRORLEVEL% 系统 返回上一条命令的错误代码。通常用非零值表示错误。

10. %HOMEDRIVE% 系统 返回连接到用户主目录的本地工作站驱动器号。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。

11. %HOMEPATH% 系统 返回用户主目录的完整路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。

12. %HOMESHARE% 系统 返回用户的共享主目录的网络路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。

13. %LOGONSERVER% 本地 返回验证当前登录会话的域控制器的名称。

14. %NUMBER_OF_PROCESSORS% 系统 指定安装在计算机上的处理器的数目。

15. %OS% 系统 返回操作系统名称。Windows 2000 显示其操作系统为 Windows_NT。

16. %PATH% 系统 指定可执行文件的搜索路径。

17. %PATHEXT% 系统 返回操作系统认为可执行的文件扩展名的列表。

18. %PROCESSOR_ARCHITECTURE% 系统 返回处理器的芯片体系结构。值：x86 或 IA64 基于Itanium

19. %PROCESSOR_IDENTFIER% 系统 返回处理器说明。

20. %PROCESSOR_LEVEL% 系统 返回计算机上安装的处理器的型号。

21. %PROCESSOR_REVISION% 系统 返回处理器的版本号。

22. %PROMPT% 本地 返回当前解释程序的命令提示符设置。由 Cmd.exe 生成。

23. %RANDOM% 系统 返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。

24. %SYSTEMDRIVE% 系统 返回包含 Windows server operating system 根目录（即系统根目录）的驱动器。

25. %SYSTEMROOT% 系统 返回 Windows server operating system 根目录的位置。

26. %TEMP% 和 %TMP% 系统和用户 返回对当前登录用户可用的应用程序所使用的默认临时目录。有些应用程序需要 TEMP，而其他应用程序则需要 TMP。

27. %TIME% 系统 返回当前时间。使用与 time /t 命令相同的格式。由 Cmd.exe 生成。有关time 命令的详细信息，请参阅 Time。

28. %USERDOMAIN% 本地 返回包含用户帐户的域的名称。

29. %USERNAME% 本地 返回当前登录的用户的名称。

30. %USERPROFILE% 本地 返回当前用户的配置文件的位置。

31. %WINDIR% 系统 返回操作系统目录的位置。

这么多系统变量,我们如何知道他的值是什么呢?
在CMD里输入??echo %WINDIR%
这样就能显示一个变量的值了!
举个实际例子,比如我们要复制文件到当前帐号的启动目录里就可以这样
copy d:\1.bat "%USERPROFILE%\「开始」菜单\程序\启动\"
%USERNAME% 本地 返回当前登录的用户的名称。??注意有空格的目录要用引号引起来

另外还有一些系统变量,他们是代表一个意思,或者一个操作!
他们分别是%0 %1 %2 %3 %4 %5 ......一直到%9 还有一个%*
%0 这个有点特殊,有几层意思,先讲%1-%9的意思.
%1 返回批处理的第一个参数
%2 返回批处理的第二个参数
%3-%9依此推类
反回批处理参数?到底怎么个返回法?
我们看这个例子,把下面的代码保存为test.BAT然后放到C盘下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
进入CMD,输入cd c:\
然后输入 test.bat 我是第一个参数 我是第二个参数??我是第三个参数??我是第四个参数
注意中间的空格,我们会看到这样的结果:
我是第一个参数 我是第二个参数 我是第三个参数 我是第四个参数
我是第一个参数
我是第二个参数
我是第三个参数
我是第四个参数
对比下代码,%1就是”我是第一个参数”??%2就是”我是第二个参数”
怎么样理解了吧!

这些%1和%9可以让批处理也能带参数运行,大大提高批处理功能!
还有一个%*??他是什么呢?他的作用不是很大,只是返回参数而已,不过他是一次返回全部参数的值,不用在输入%1 %2来确定一个个的
例子：

1. @echo off

2. echo %*

同样保存为test.bat 放到C盘
进入CMD,输入cd c:\
然后输入 test.bat 我是第一个参数 我是第二个参数??我是第三个参数??我是第四个参数
可以看到他一次把全部参数都显示出来了

好现在开始讲那个比较特殊的%0
%0??这个不是返回参数的值了,他有两层意思!
第一层意思:返回批处理所在绝对路径
例子:

1. @echo off

2. echo %0

3. pause

保存为test.BAT放在桌面运行,会显示如下结果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把当前批处理执行的所在路经打印出来了,这就是返回批处理所在绝对路径的意思
第二层意思:无限循环执行BAT
例子:

1. @echo off

2. net user

3. %0

保存为BAT执行,他就会无限循环执行net user这条命令,直到你手动停止.
龙卷风补充：其实%0就是第一参数%1前面那个参数，当然就是批处理文件名（包括路径）。
以上就是批处理中的一些系统变量.

2，自定义变量

自定义变量就是由我们来给他赋予值的变量
要使用自定义变量就得使用set命令了,看例子：

1. @echo off

2. set var=我是值

3. echo %var%

4. pause

保存为BAT执行,我们会看到CMD里返回一个??"我是值"
var为变量名,=号右变的是要给变量的值
这就是最简单的一种设置变量的方法了
如果我们想让用户手工输入变量的值,而不是在代码里指定,可以用用set命令的/p参数
例子:

1. @echo off

2. set /p var=请输入变量的值

3. echo %var%

4. pause

var变量名??=号右边的是提示语,不是变量的值
变量的值由我们运行后自己用键盘输入!?

六、交互界面设计

看看高手设计的菜单界面吧：

1. @echo off

2. cls

3. title 终极多功能修复

4. :menu

5. cls

6. color 0A

7. echo.

8. echo ==============================

9. echo 请选择要进行的操作，然后按回车

10. echo ==============================

11. echo.

12. echo 1.网络修复及上网相关设置,修复IE,自定义屏蔽网站

13. echo.

14. echo 2.病毒专杀工具，端口关闭工具,关闭自动播放

15. echo.

16. echo 3.清除所有多余的自启动项目，修复系统错误

17. echo.

18. echo 4.清理系统垃圾,提高启动速度

19. echo.

20. echo Q.退出

21. echo.

22. echo.

23. :cho

24. set choice=

25. set /p choice= 请选择:

26. IF NOT "%choice%"=="" SET choice=%choice:~0,1%

27. if /i "%choice%"=="1" goto ip

28. if /i "%choice%"=="2" goto setsave

29. if /i "%choice%"=="3" goto kaiji

30. if /i "%choice%"=="4" goto clean

31. if /i "%choice%"=="Q" goto endd

32. echo 选择无效，请重新输入

33. echo.

34. goto cho

七、if…else…条件语句

DOS条件语句主要有以下形式：
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增强用法：IF [/I] string1 compare-op string2 command
增强用法中加上/I就不区分大小写了!
增强用法中还有一些用来判断数字的符号：

1. EQU - 等于

2. NEQ - 不等于

3. LSS - 小于

4. LEQ - 小于或等于

5. GTR - 大于

6. GEQ - 大于或等于

上面的command命令都可以用小括号来使用多条命令的组合，包括else子句，组合命令中可以嵌套使用条件或循环命令。
例如:

1. IF EXIST filename (

2. del filename

3. ) ELSE (

4. echo filename missing

5. )

八、循环语句

1、指定次数循环

FOR /L %variable IN (start,step,end) DO command [command-parameters]
组合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)?

2、对某集合执行循环语句

FOR %%variable IN (set) DO command [command-parameters]
??%%variable??指定一个单一字母可替换的参数。
??(set)? ?? ?指定一个或一组文件。可以使用通配符。
??command? ?对每个文件执行的命令，可用小括号使用多条命令组合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
含义：检查以 [drive:]path 为根的目录树，指向每个目录中的FOR 语句。如果在 /R 后没有指定目录，则使用当前目录。如果集仅为一个单点(.)字符，则枚举该目录树。
同前面一样，command可以用括号来组合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、条件循环

? ? 上面的循环结构是用for命令来实现的，for命令循环有一个缺点，就是整个循环被当作一条命令语句，涉及到变量延迟的问题。
利用goto语句和条件判断，dos可以实现条件循环，很简单啦，看例子：

例1：

1. @echo off

2. set var=0

3. rem ************循环开始了

4. :continue

5. set /a var+=1

6. echo 第%var%次循环

7. if %var% lss 100 goto continue

8. rem ************循环结束了

9. echo 循环执行完毕

10. pause

例2：

1. @echo off

2. set var=100

3. rem ************循环开始了

4. :continue

5. echo 第%var%次循环

6. set /a var-=1

7. if %var% gtr 0 goto continue

8. rem ************循环结束了

9. echo 循环执行完毕

10. pause

九、子程序

在批处理程序中可以调用外部可运行程序，比如exe程序，也可调用其他批处理程序，这些也可以看作子程序，但是不够方便，如果被调用的程序很多，就显得不够简明了，很繁琐。
? ?在windowsXP中，批处理可以调用本程序中的一个程序段，相当于子程序，这些子程序一般放在主程序后面。
子程序调用格式：
??CALL :label arguments

子程序语法：
??:label
??command1
??command2
??......
??commandn
??goto :eof

在子程序段中，参数%0指标签:label
子过程一般放在最后，并且注意在主程序最后要加上exit或跳转语句，避免错误的进入子过程。
子程序和主程序中的变量都是全局变量，其作用范围都是整个批处理程序。
传至子程序的参数在call语句中指定，在子程序中用%1、%2至%9的形式调用，而子程序返回主程序的数据只需在调用结束后直接引用就可以了，当然也可以指定返回变量，请看下面的例子。
子程序例1：

1. @echo off

2. call :sub return

3. echo 子程序返回值：%return%

4. pause

5. goto :eof

7. :sub

8. set %1=你好

9. goto :eof

运行结果：你好

子程序例2：设计一个求多个整数相加的子程序

1. @echo off

2. set sum=0

3. call :sub 10 20 35 40 50

4. echo 数据求和结果：%sum%

5. pause

6. goto :eof

8. :sub

9. rem 参数1为返回变量名称

10. set /a sum+=%1

11. shift /1

12. if not "%1"=="" goto sub

13. goto :eof

运行结果：155

十、用ftp命令实现自动下载

ftp是常用的下载工具，ftp界面中有40多个常用命令，自己学习了，不介绍了。这里介绍如何用dos命令行调用ftp命令，实现ftp自动登录，并上传下载，并自动退出ftp程序。
其实可以将ftp命令组合保存为一个文本文件，然后用以下命令调用即可。
ftp??-n -s:[[drive:]path]filename

上面的filename为ftp命令文件，包括登录IP地址，用户名、密码、操作命令等
例：

1. open 90.52.8.3 ＃打开ip

2. user iware ＃用户为iware

3. password8848 ＃密码

4. bin ＃二进制传输模式

5. prompt

6. cd tmp1 ＃切换至iware用户下的tmp1目录

7. pwd

8. lcd d:\download ＃本地目录

9. mget * ＃下载tmp1目录下的所有文件

10. bye ＃退出ftp

十一、用7-ZIP实现命令行压缩和解压功能

语法格式：（详细情况见7-zip帮助文件，看得头晕可以跳过，用到再学）
7z <command> [<switch>...] <base_archive_name> [<arguments>...]
7z.exe的每个命令都有不同的参数<switch>,请看帮助文件
<base_archive_name>为压缩包名称
<arguments>为文件名称，支持通配符或文件列表
其中，7z是至命令行压缩解压程序7z.exe，<command>是7z.exe包含的命令，列举如下：

a： Adds files to archive. 添加至压缩包
a命令可用参数：
??-i (Include)
??-m (Method)
??-p (Set Password)
??-r (Recurse)
??-sfx (create SFX)
??-si (use StdIn)
??-so (use StdOut)
??-ssw (Compress shared files)
??-t (Type of archive)
??-u (Update)
??-v (Volumes)
??-w (Working Dir)
??-x (Exclude)?

b： Benchmark?
d： Deletes files from archive. 从压缩包中删除文件
d命令可用参数：
??-i (Include)
??-m (Method)
??-p (Set Password)
??-r (Recurse)
??-u (Update)
??-w (Working Dir)
??-x (Exclude)?

e： Extract解压文件至当前目录或指定目录
e命令可用参数：
??-ai (Include archives)
??-an (Disable parsing of archive_name)
??-ao (Overwrite mode)
??-ax (Exclude archives)
??-i (Include)
??-o (Set Output Directory)
??-p (Set Password)
??-r (Recurse)
??-so (use StdOut)
??-x (Exclude)
??-y (Assume Yes on all queries)?

l： Lists contents of archive.
t： Test?
u： Update?

x： eXtract with full paths用文件的完整路径解压至当前目录或指定目录
x命令可用参数：
??-ai (Include archives)
??-an (Disable parsing of archive_name)
??-ao (Overwrite mode)
??-ax (Exclude archives)
??-i (Include)
??-o (Set Output Directory)
??-p (Set Password)
??-r (Recurse)
??-so (use StdOut)
??-x (Exclude)
??-y (Assume Yes on all queries)?

十二、调用VBScript程序

使用 Windows 脚本宿主，可以在命令提示符下运行脚本。CScript.exe 提供了用于设置脚本属性的命令行开关。

用法：CScript 脚本名称 [脚本选项...] [脚本参数...]
选项：
//B?????? 批模式：不显示脚本错误及提示信息
//D?????? 启用 Active Debugging
//E:engine?? 使用执行脚本的引擎
//H:CScript 将默认的脚本宿主改为 CScript.exe
//H:WScript 将默认的脚本宿主改为 WScript.exe （默认）
//I?????? 交互模式（默认，与 //B 相对)
//Job:xxxx?? 执行一个 WSF 工作
//Logo??? 显示徽标（默认）
//Nologo 不显示徽标：执行时不显示标志
//S?????? 为该用户保存当前命令行选项
//T:nn??? 超时设定秒：允许脚本运行的最长时间
//X?????? 在调试器中执行脚本
//U?????? 用 Unicode 表示来自控制台的重定向 I/O

“脚本名称”是带有扩展名和必需的路径信息的脚本文件名称，如d:/admin/vbscripts/chart.vbs。
“脚本选项和参数”将传递给脚本。脚本参数前面有一个斜杠 (/)。每个参数都是可选的；但不能在未指定脚本名称的情况下指定脚本选项。如果未指定参数，则 CScript 将显示 CScript 语法和有效的宿主参数。

十三、将批处理转化为可执行文件

由于批处理文件是一种文本文件，任何人都可以对其进行随便编辑，不小心就会把里面的命令破坏掉，所以如果将其转换成.com格式的可执行文件，不仅执行效率会大大提高，而且不会破坏原来的功能，更能将优先级提到最高。Bat2Com就可以完成这个转换工作。
小 知识：在DOS环境下，可执行文件的优先级由高到低依次为.com>.exe>.bat>.cmd，即如果在同一目录下存在文件名相同 的这四类文件，当只键入文件名时，DOS执行的是name.com，如果需要执行其他三个文件，则必须指定文件的全名，如name.bat。
这是一个只有5.43K大小的免费绿色工具，可以运行在纯DOS或DOS窗口的命令行中，用法：Bat2Com
FileName，这样就会在同一目录下生成一个名为FileNme.com的可执行文件，执行的效果和原来的.bat文件一样。

十四、时间延迟

什么是时间延迟？顾名思义，就是执行一条命令后延迟一段时间再进行下一条命令。
延迟的应用见下节：“模拟进度条”。
1、利用ping命令延时
例：

1. @echo off

2. echo 延时前：%time%

3. ping /n 3 127.0.0.1 >nul

4. echo 延时后：%time%

5. pause

用到了ping命令的“/n”参数，表示要发送多少次请求到指定的ip。本例中要发送3次请求到本机的ip（127.0.0.1）。127.0.0.1可简写为127.1。“>nul”就是屏蔽掉ping命令所显示的内容。

2、利用for命令延时
例：

1. @echo off

2. echo 延时前：%time%

3. for /l %%i in (1,1,5000) do echo %%i>nul

4. echo 延时后：%time%

5. pause

原理很简单，就是利用一个计次循环并屏蔽它所显示的内容来达到延时的目的。

3、利用vbs延迟函数，精确度毫秒，误差1000毫秒内

1. @echo off

2. echo %time%

3. call :delay 5000

4. echo %time%

5. pause

7. exit

8. :delay

9. echo WScript.Sleep %1>delay.vbs

10. CScript //B delay.vbs

11. del delay.vbs

12. goto :eof

运行显示：

10:44:06.45
10:44:11.95
请按任意键继续. . .
上面的运行结果显示实际延时了5500毫秒，多出来的500毫秒时建立和删除临时文件所耗费的时间。误差在一秒之内。

4、仅用批处理命令实现任意时间延迟，精确度10毫秒，误差50毫秒内
仅用批处理命令就可以实现延迟操作。
例：

1. @echo off

2. set /p delay=请输入需延迟的毫秒数：

3. set TotalTime=0

4. set NowTime=%time%

5. ::读取起始时间，时间格式为：13:01:05.95

6. echo 程序开始时间：%NowTime%

7. :delay_continue

8. set /a minute1=1%NowTime:~3,2%-100

9. ::读取起始时间的分钟数

10. set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000

11. ::将起始时间的秒数转为毫秒

12. set NowTime=%time%

13. set /a minute2=1%NowTime:~3,2%-100

14. :: 读取现在时间的分钟数

15. set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000

16. ::将现在时间的秒数转为毫秒

17. set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%

18. if %TotalTime% lss %delay% goto delay_continue

19. echo 程序结束时间：%time%

20. echo 设定延迟时间：%delay%毫秒

21. echo 实际延迟时间：%TotalTime%毫秒

22. pause

运行显示：
? ?请输入需延迟的毫秒数：6000
? ?程序开始时间：15:32:16.37
? ?程序结束时间：15:32:22.37
? ?设定延迟时间：6000毫秒
? ?实际延迟时间：6000毫秒
? ?请按任意键继续. . .

实现原理：首先设定要延迟的毫秒数，然后用循环累加时间，直到累加时间大于等于延迟时间。
误差：windows系统时间只能精确到10毫秒，所以理论上有可能存在10毫秒误差。
? ?? ?经测试，当延迟时间大于500毫秒时，上面的延迟程序一般不存在误差。当延迟时间小于500毫秒时，可能有几十毫秒误差，为什么？因为延迟程序本身也是有运行时间的，同时系统时间只能精确到10毫秒。

为了方便引用，可将上面的例子改为子程序调用形式：

1. @echo off

2. echo 程序开始时间：%Time%

3. call :delay 10

4. echo 实际延迟时间：%totaltime%毫秒

5. echo 程序结束时间：%time%

6. pause

7. exit

9. ::-----------以下为延时子程序--------------------

10. :delay

11. @echo off

12. if "%1"=="" goto :eof

13. set DelayTime=%1

14. set TotalTime=0

15. set NowTime=%time%

16. ::读取起始时间，时间格式为：13:01:05.95

17. :delay_continue

18. set /a minute1=1%NowTime:~3,2%-100

19. set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000

20. set NowTime=%time%

21. set /a minute2=1%NowTime:~3,2%-100

22. set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000

23. set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%

24. if %TotalTime% lss %DelayTime% goto delay_continue

25. goto :eof

十五、模拟进度条

下面给出一个模拟进度条的程序。如果将它运用在你自己的程序中，可以使你的程序更漂亮。

1. @echo off

2. mode con cols=113 lines=15 &color 9f

3. cls

4. echo.

5. echo 程序正在初始化. . .

6. echo.

7. echo ┌──────────────────────────────────────┐

8. set /p = ■<nul

9. for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul

10. echo 100%%

11. echo └──────────────────────────────────────┘

12. pause

“set /p a=■<nul”的意思是：只显示提示信息“■”且不换行，也不需手工输入任何信息，这样可以使每个“■”在同一行逐个输出。“ping /n 0 127.1>nul”是输出每个“■”的时间间隔，ping /n 0表示不执行这个命令，所以会比ping出去的时间更短，也就是即每隔多少时间最短输出一个“■”。当然你也可以改为1或2或3等使时间延长

PS:上面的代码执行太快了，并且第一个出现的节奏和后面的不协调，我稍微修改了点，如下：

1. echo.

2. echo ┌──────────────────────────────────────┐

3. ping 127.0.0.1 >nul /n 1 & set /p=<nul

4. for /L %%i in (1 1 39) do set /p a=■<nul & ping /n 1 127.0.0.1>nul

5. echo 100%%

6. echo └──────────────────────────────────────┘

7. pause

十六、特殊字符的输入及应用

开始 -> 运行 -> 输入cmd -> edit -> ctrl+p（意思是允许输入特殊字符）-> 按ctrl+a将会显示笑脸图案。
（如果要继续输入特殊字符请再次按ctrl+p，然后ctrl+某个字母）
以上是特殊字符的输入方法，选自[英雄]教程，很管用的。也就是用编辑程序edit输入特殊字符，然后保存为一文本文件，再在windows下打开此文件，复制其中的特殊符号即可。
一些简单的特殊符号可以在dos命令窗口直接输入，并用重定向保存为文本文件。
例：

C:>ECHO ^G>temp.txt

“^G”是用Ctrl＋G或Alt＋007输入(按住Alt后，只能按小键盘的数字)，输入多个^G可以产生多声鸣响。
特殊字符的应用也很有意思，这里仅举一例：退格键(输入方法：开始 -> 运行 -> 输入cmd -> edit -> ctrl+p ->退格键)
退格键表示删除左边的字符，此键不能在文档中正常输入，但可以通过edit编辑程序录入并复制出来。即“”。
利用退格键，配合空格覆盖，可以设计闪烁文字效果
例：文字闪烁，可以使用Ctrl+C组合键来强行终运行：

1. @echo off

2. :start

3. set/p=床前明月光<nul

4. ::显示文字，光标停于行尾

6. ping -n 0 127.0.0.1>nul

7. ::设置延迟时间

9. set /p a=<nul

10. :: 输出一些退格符将光标置于该行的最左端（退格符的数量可以自己调整）。

12. ping -n 0 127.0.0.1>nul

13. ::设置延迟时间

15. set /p a= <nul

16. ::输出空格将之前输出的文字覆盖掉。

18. set /p a=<nul

19. ::再次输出退格符将光标置于该行的最左端，这里的退格符数量一定不能比前面的

21. 空格数少，否则光标不能退到最左端。

23. ping -n 0 127.0.0.1>nul

24. ::设置延迟时间

26. goto start

主要是利用set命令的/p，表示后等号面的字符都是提示字符，然后在用退格键，让光标置于该行的最左端，但是原来的文字还在，然后使用空格作为输入提示符，所以就会覆盖前面的文字，然后再次输出退格符将光标置于该行的最左端，循环执行。如果你把ping命令的次数改为4，使延迟增长，就能看到光标的位置变化了。

例：输出唐诗一首，每行闪动多次

1. @echo off

2. setlocal enabledelayedexpansion

4. set str=床前明月光 疑是地上霜 举头望明月 低头思故乡

5. ::定义字符串str

6. for %%i in (%str%) do (

7. rem 由于str中含有空格，则以空格为分隔符将str中的每一个部分依次赋给变量%%i。

8. set char=%%i

9. echo.

10. echo.

11. for /l %%j in (0,1,5) do (

12. set/p=!char:~%%j,1!<nul

13. rem 依次取出变量char中的每一个字符，并显示。

14. ping -n 0 127.0.0.1>nul

15. rem 设置输出每个字符的时间延迟。

16. )

17. call :hero %%i

18. )

19. pause>nul

20. exit

22. :hero

23. for /l %%k in (1,1,10) do (

24. ping /n 0 127.0.0.1>nul

25. set /p a=<nul

26. set /p a= <nul

27. set /p a=<nul

28. ping /n 0 127.0.0.1>nul

29. set /p a=%1<nul

30. )

31. ::文字闪动

32. goto :eof

十七、随机数（%random%）的应用技巧

%RANDOM% 系统变量 返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。
2的15次方等于32768，上面的0～32767实际就是15位二进制数的范围。
那么，如何获取100以内的随机数呢？很简单，将%RANDOM%按100进行求余运算即可，见例子。
例：生成5个100以内的随机数

1. @echo off

2. setlocal enabledelayedexpansion

3. for /L %%i in (1 1 5) do (

4. set /a randomNum=!random!%%100

5. echo 随机数：!randomNum!

6. )

7. pause

运行结果：（每次运行不一样）
随机数：91
随机数：67
随机数：58
随机数：26
随机数：20
请按任意键继续. . .

求余数运算set /a randomNum=!random!%%100中的100可以是1～32768之间的任意整数。
总结：利用系统变量%random%，求余数运算%%，字符串处理等，可以实现很多随机处理。

通过上面的学习，我们知道，%random%可以产生0到32767之间的随机数，但是，如何才能得到一定范围内的随机数呢？?
我们可以使用通用的算法公式如下：?
通用的公式%random%%%(max-min+1)+min来产生[min,max]区间里的随机数，
注：批处理中求模得用两个%%符号。?
比如，我们想获得4到12之间的随机数，就可以这样来使用，代码如下：

1. @REM 产生10个[4,12]间的随机数

2. @echo off

3. REM 启用延迟环境变量扩展

4. setlocal enabledelayedexpansion

5. REM 设置随机数的最小和最大值以及求模用的变量

6. set min=4

7. set max=12

8. set /a mod=!max!-!min!+1

10. for /l %%i in (1,1,10) do (

11. REM 产生[min,max]之间的随机数

12. set /a r=!random!%%!mod!+!min!

13. echo.

14. echo 随机数%%i：!r!)

示例：生成给定位数的随机密码
解答思路：将26个英文字母或10数字以及其它特殊字符组成一个字符串，随机抽取其中的若干字符。
方案1：

1. @echo off

2. call :randomPassword 5 pass1 pass2

3. echo %pass1% %pass2%

4. pause

5. exit

7. :randomPassword

8. ::---------生成随机密码

9. ::---------%1为密码长度，%2及以后为返回变量名称

10. ::---------for命令最多只能区分31个字段

11. @echo off

12. set password_len=%1

13. if not defined password_len goto :eof

14. if %password_len% lss 1 goto :eof

15. set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z

16. set return=

17. set num=0

18. :randomPassword1

19. set /a num+=1

20. set /a numof=%random%%%26+1

21. for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i

22. if %num% lss %password_len% goto randomPassword1

23. if not "%2"=="" set %2=%return%

24. shift /2

25. if not "%2"=="" goto randomPassword

26. goto :eof

方案2：（最优）

1. @echo off

2. call :randomPassword 6 pass1 pass2 pass3

3. echo %pass1% %pass2% %pass3%

4. pause

5. exit

7. :randomPassword

8. ::---------生成随机密码

9. ::---------%1为密码长度，%2及以后为返回变量名称

10. ::---------goto循环、变量嵌套、命令嵌套

11. @echo off

12. if "%1"=="" goto :eof

13. if %1 lss 1 goto :eof

14. set password_len=%1

15. set return=

16. set wordset=abcdefghijklmnopqrstuvwxyz023456789_

17. ::---------------------------循环

18. :randomPassword1

19. ::---生成0-35之间的随即数

20. set /a numof=%random%%%36

21. ::---在wordset变量中，从的随即生成的0-35的下一个取出一个字符

22. call set return=%return%%%wordset:~%numof%,1%%

23. set /a password_len-=1

24. if %password_len% gtr 0 goto randomPassword1

25. ::---------------------------循环

26. if not "%2"=="" set %2=%return%

27. shift /2

28. if not "%2"=="" goto randomPassword

29. goto :eof

十八、变量嵌套 与 命令嵌套

和其它编程语言相比，dos功能显得相对简单，要实现比较复杂的功能，需要充分运用各种技巧，变量嵌套与命令嵌套就是此类技巧之一。
先复习一下前面的“字符串截取”的关键内容：
**********************************************
截取功能统一语法格式为：%a:~[m[,n]]%
**********************************************
方括号表示可选，%为变量标识符，a为变量名，不可少，冒号用于分隔变量名和说明部分，符号～可以简单理解为“偏移”即可，m为偏移量（缺省为0），n为截取长度（缺省为全部）。
百分号如果需要当成单一字符，必须写成%%
以上是dos变量处理的通用格式，如果其中的m、n为变量，那么这种情况就是变量嵌套了。
比如设变量word为“abcdefghij”，变量num为“123456789”
%word:~4,1%为e，其中4可以从变量num中取值，即%num:~3,1%，写成组合形式如下：
%word:~%num:~3,1%,1% 经测试这种写法不能正确执行，写成%word:~(%num:~3,1%),1%同样不行，那么，怎么实现这种变量嵌套呢？这就必须结合命令嵌套。
什么是命令嵌套呢？简单的说，首先用一条dos命令生成一个字符串，而这个字符串是另一条dos命令，用call语句调用字符串将其执行，从而得到最终结果。
例：用call语句实现命令嵌套

1. @echo off

2. set str1=aaa echo ok bbb

3. echo 初始字符串：%str1%

4. echo 生成命令字符串如下：

5. echo %str1:~4,7%

6. echo 运行命令字符串生成最终结果为：

7. call %str1:~4,7%

8. pause

运行显示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
运行命令字符串生成最终结果为：
ok
请按任意键继续. . .

十九、乱码问题

问题：出现中文乱码

解决方案：编码方式更改为ANSI

或者如：

1. @echo off

3. rem 声明采用utf-8编码

4. chcp 65001

   ?(820条消息) bat脚本的常用特殊符号_tuonioooo的博客-CSDN博客_bat转义符号