通达信枢轴点指标公式，自动画支撑位和阻力位

枢轴点（Pivot Points）是一种确定可能的支撑位和阻力位的技术分析指标，常用于日内交易，利用该指标可以估计当天的潜在价格范围，判断潜在转折点，还可以作为止盈止损位用来设定目标，此外也可以用于确认突破。枢轴点是通过计算前一交易日的最高价、最低价和收盘价来确定的，因此这些值之间的范围越大，当天计算出的支撑位、阻力位的价位间距就越大。

枢轴点有多种计算方法，其中常用的方法是经典的枢轴点，计算公式如下：

1、枢轴点（Pivot Point）= (前一日最高价 + 前一日最低价 + 前一日收盘价) / 3

2、第一个阻力位（R1）= (2 * 枢轴点) - 前一日最低价

3、第一个支撑位（S1）= (2 * 枢轴点) - 前一日最高价

4、第二个阻力位（R2）= 枢轴点 + (第一个阻力位 - 第一个支撑位)

5、第二个支撑位（S2）= 枢轴点?- (第一个阻力位 - 第一个支撑位)

6、第三个阻力位（R3）= 前一日最高价 +?2 * (枢轴点 - 前一日低价)

7、第三个支撑位（S3）= 枢轴点?- 2 * (前一日最高价 - 枢轴点)

从上面的公式可以看出，最终有7个点位可以利用：1个枢轴点、3个阻力位、3个支撑位。如果开盘价高于枢轴点，并且价格保持在枢轴点之上，当日更可能倾向于看涨；如果开盘价低于枢轴点，并且价格保持在枢轴点下方，当日更可能倾向于看跌。

虽然R1、R2和R3的含义是，当市场上涨时，它们可能会充当阻力，但如果价格在它们上方运行，它们也可以充当价格回调时的支撑。S1、S2和 S3也是如此，当价格跌破支撑位时，可以在反弹时充当阻力位。

一、枢轴点指标公式（主图）

思路：枢轴点的公式看起来不难，但是因为要每个交易日重新计算，所以DATE<>REF(DATE,1)来区分不同的日期，并计算出前一日的最高价、最低价和收盘价。公式只适用于日线以下周期，比如1分钟、5分钟、15分钟图等。

FB:=DATE<>REF(DATE,1);

T:=BARSLAST(FB);

HH:=HHV(H,T+1);

LL:=LLV(L,T+1);

RH:=REF(HH,T+1);

RL:=REF(LL,T+1);

RC:=REF(C,T+1);

P:IF(PERIOD<5,(RH+RL+RC)/3,DRAWNULL),DOTLINE;

R1:IF(PERIOD<5,2*P-RL,DRAWNULL);

S1:IF(PERIOD<5,2*P-RH,DRAWNULL);

R2:IF(PERIOD<5,P+(R1-S1),DRAWNULL);

S2:IF(PERIOD<5,P-(R1-S1),DRAWNULL);

R3:IF(PERIOD<5,RH+2*(P-RL),DRAWNULL);

S3:IF(PERIOD<5,RL-2*(RH-P),DRAWNULL);

二、枢轴点指标公式（分时图）

枢轴点分时图指标公式比较复杂一些，即时行情函数DYNAINFO只能获取前一日的收盘价，没有直接获取前一日的最高价和最低价的函数，只能自己编写。

1、首先新建一个技术指标公式并保存，名称为“HL”。这个公式的目的是获取前一日的最高价和最低价。

RH:REF(H,1);

RL:REF(L,1);

2、再建一个技术指标公式用于加载到分时图，公式引用上面HL公式的日线数据，即前一日最高价、前一个最低价。

RH:=HL.RH#DAY;

RL:=HL.RL#DAY;

P:(RH+RL+DYNAINFO(3))/3,DOTLINE;

R1:2*P-RL;

S1:2*P-RH;

R2:P+(R1-S1);

S2:P-(R1-S1);

R3:RH+2*(P-RL);

S3:RL-2*(RH-P);

注意：因为公式引用了前一日的价格，需要通过盘后数据下载，把日线数据补充完整，不然计算结果不准确。

关注技术Pie，学习更多通达信指标公式编写知识。版权所有，转载请注明出处。

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎。