通达信Vortex涡旋指标选股公式，灵感来自于DMI指标和水流涡旋运动

Vortex涡旋指标是由Etienne Botes和Douglas Siepman开发的，目的在于评估并预测价格趋势的强度和方向，其灵感来自于Welles Wilder的DMI指标和奥地利发明家Viktor Schauberger的水流涡旋运动，用涡旋运动来模仿市场的运动。Vortex指标包含两根线，正向涡旋（+VI）和负向涡旋（-VI），通过比较每日最高价和最低价之间的变化来衡量股票价格的上升和下降压力并确定价格趋势。

Vortex指标围绕1上下波动，正向涡旋（+VI）用于识别上升趋势运动，负向涡旋（-VI）用于识别下降趋势运动。在价格趋势强劲的时期，两条线的距离会拉大，反之两条线距离越近，则表示趋势越弱或价格处于相对稳定的时期。当正向涡旋（+VI）上穿负向涡旋（-VI）时，表明可能出现上升势头，如果 +VI 保持在 -VI 以上，则进一步巩固了上升趋势。反之当 +VI下穿?-VI 时，则表明可能出现下跌势头，如果 +VI 保持在 -VI 以下，则进一步确认了下降趋势。

一、Vortex指标计算公式及副图指标

Vortex指标计算公式如下：

1、计算+VM、-VM

+VM?= 当日最高价 - 前一日最低价

-VM?= 前一日最高价 - 当日最低价

2、计算加总+VM、加总-VM

加总+VM = 一段时间的+VM之和

加总-VM = 一段时间的-VM之和

3、计算加总真实波幅

加总真实波幅 = 一段时间的真实波幅之和

真实波幅之前介绍过多次了，这里不再赘述。

4、计算+VI、-VI，也就是指标的两条线

+VI = 加总+VM ÷?加总真实波幅

-VI = 加总-VM ÷?加总真实波幅

Vortex指标副图指标公式：

N:=14;

VMP:=ABS(H-REF(L,1));

VMM:=ABS(L-REF(H,1));

VMPS:=SUM(VMP,N);

VMMS:=SUM(VMM,N);

TRS:=SUM(MAX(MAX(H-L,ABS(H-REF(C,1))),ABS(REF(C,1)-L)),N);

PVI:VMPS/TRS;

MVI:VMMS/TRS;

二、Vortex主图指标公式

思路：上文提到+VI、-VI两条线距离比较近的时候，表示趋势弱势或处于相对稳定的时期。当+VI上穿-VI，可能出现上升势头。可以用+VI、-VI之差来限制两条线的距离来表示趋势弱势或相对稳定，在趋势弱势或相对稳定保持一段时间后，用+VI上穿-VI捕捉可能的上升趋势。

N:=14;

VMP:=ABS(H-REF(L,1));

VMM:=ABS(L-REF(H,1));

VMPS:=SUM(VMP,N);

VMMS:=SUM(VMM,N);

TRS:=SUM(MAX(MAX(H-L,ABS(H-REF(C,1))),ABS(REF(C,1)-L)),N);

PVI:=VMPS/TRS;

MVI:=VMMS/TRS;

JL:=ABS(PVI-MVI)<0.4;

TJ:=EVERY(JL,20) AND CROSS(PVI,MVI);

T:=BARSLAST(TJ);

A1:=COUNT(PVI<0.8,T)>=1;

A2:=CROSS(PVI,MVI);

A3:=C>MA(C,5);

AA:=REF(A1,1) AND A2 AND A3;

XG:=AA AND COUNT(AA,T)=1 AND T<20;

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

三、Vortex指标选股公式

N:=14;

VMP:=ABS(H-REF(L,1));

VMM:=ABS(L-REF(H,1));

VMPS:=SUM(VMP,N);

VMMS:=SUM(VMM,N);

TRS:=SUM(MAX(MAX(H-L,ABS(H-REF(C,1))),ABS(REF(C,1)-L)),N);

PVI:=VMPS/TRS;

MVI:=VMMS/TRS;

JL:=ABS(PVI-MVI)<0.4;

TJ:=EVERY(JL,20) AND CROSS(PVI,MVI);

T:=BARSLAST(TJ);

A1:=COUNT(PVI<0.8,T)>=1;

A2:=CROSS(PVI,MVI);

A3:=C>MA(C,5);

AA:=REF(A1,1) AND A2 AND A3;

XG:AA AND COUNT(AA,T)=1 AND T<20;

关注技术Pie，学习更多通达信指标公式编写知识。版权所有，转载请注明出处。

?

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎。