【大数据进阶第三阶段之Hive学习笔记】Hive的数据类型与数据操作

建表语法
CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name?
[(col_name data_type [COMMENT col_comment], ...)]?
[COMMENT table_comment]?
[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]?
[CLUSTERED BY (col_name, col_name, ...)?
[SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS]?
[ROW FORMAT row_format]?
[STORED AS file_format]?
[LOCATION hdfs_path]
?

字段解释说明：
（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。?

（2）EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。

（3）COMMENT：为表和列添加注释。

（4）PARTITIONED BY创建分区表

（5）CLUSTERED BY创建分桶表

（6）SORTED BY不常用

（7）ROW FORMAT

DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]

? [MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]

| SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, …)]

用户在建表的时候可以自定义SerDe或者使用自带的SerDe。如果没有指定ROW FORMAT 或者ROW FORMAT DELIMITED，将会使用自带的SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的SerDe，Hive通过SerDe确定表的具体的列的数据。

SerDe是Serialize/Deserilize的简称，目的是用于序列化和反序列化。

（8）STORED AS指定存储文件类型

常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）

如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。

（9）LOCATION ：指定表在HDFS上的存储位置。

（10）LIKE允许用户复制现有的表结构，但是不复制数据。

2.4.1、内部表

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive会（或多或少地）控制着数据的生命周期。Hive默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/opt/hive/warehouse)所定义的目录的子目录下。当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

普通创建表
create table if not exists student2(
id int, name string
)
row format delimited fields terminated by '\t';

根据查询结果创建表（查询的结果会添加到新创建的表中）
create table if not exists student3 as select id, name from student;

根据已经存在的表结构创建表
create table if not exists student4 like student;

查询表的类型
desc formatted student2;
?

2.4.2、外部表

因为表是外部表，所以Hive并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。?

管理表和外部表的使用场景
每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。

案例详解
分别创建employee外部表，并向表中导入数据。

Michael|Montreal,Toronto|Male,30|DB:80|Product:DeveloperLead
Will|Montreal|Male,35|Perl:85|Product:Lead,Test:Lead
Shelley|New York|Female,27|Python:80|Test:Lead,COE:Architect
Lucy|Vancouver|Female,57|Sales:89|Sales:Lead

建表语句
创建员工表

create external table if not exists employee(
name string,
address array<string>,
personalInfo array<string>,
technol map<string,int>,
jobs map<string,string>)
row format delimited
fields terminated by '|'
collection items terminated by ','
map keys terminated by ':'
lines terminated by '\n';

向外部表中导入数据

load data local inpath '/root/employee.txt' into table employee;

查询结果

select * from employee;

2.4.3管理表与外部表的互相转换

修改内部表student2为外部表
alter table student2 set tblproperties('EXTERNAL'='TRUE');

修改外部表student2为内部表
alter table student2 set tblproperties('EXTERNAL'='FALSE');

注意：('EXTERNAL'='TRUE')和('EXTERNAL'='FALSE')为固定写法，区分大小写！?

2.5、分区表（partition）

分区表实际上就是对应一个HDFS文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

2.5.1、分区表基本操作
数据

10,ACCOUNTING,NEW YORK
10,ACCOUNTING,NEW YORK
10,ACCOUNTING,NEW YORK
20,RESEARCH,DALLAS
20,RESEARCH,DALLAS
20,RESEARCH,DALLAS
30,SALES,CHICAGO
30,SALES,CHICAGO

1．引入分区表（需要根据日期对日志进行管理）

/opt/hive/warehouse/log_partition/20170702/20170702.log
/opt/hive/warehouse/log_partition/20170703/20170703.log
/opt/hive/warehouse/log_partition/20170704/20170704.log

2．创建分区表语法

create table dept_partition(
deptno int, dname string, loc string
)
partitioned by (month string)
row format delimited fields terminated by ',';

3．加载数据到分区表中

load data local inpath '/opt/dept.txt' into table default.dept_partition partition(month='201707’);
load data local inpath '/opt/dept.txt' into table default.dept_partition partition(month='201708’);
load data local inpath '/opt/dept.txt' into table default.dept_partition partition(month='201709’);

4．查询分区表中数据

单分区查询

select * from dept_partition where month='201709';

多分区联合查询

select * from dept_partition where month='201709'
union
select * from dept_partition where month='201708'
union
select * from dept_partition where month='201707';
?

注意：?

Hive 1.2.0之前的版本仅支持UNION ALL，其中重复的行不会被删除。

Hive 1.2.0和更高版本中，UNION的默认行为是从结果中删除重复的行。

5．增加分区

alter table dept_partition add partition(month='201706') ;

alter table dept_partition add partition(month='201705') partition(month='201704');

6．删除分区

alter table dept_partition drop partition (month='201704');

alter table dept_partition drop partition (month='201705'), partition (month='201706')

7．查看分区表有多少分区

show partitions dept_partition;

8．查看分区表结构

desc formatted dept_partition;

2.6、修改表

2.6.1重命名表

语法
ALTER TABLE table_name RENAME TO new_table_name

实例
alter table dept_partition2 rename to dept_partition3;
?

2.6.2增加/修改/替换列信息

语法
更新列?

ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

增加和替换列

ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)?

注：ADD是代表新增一字段，字段位置在所有列后面(partition列前)，REPLACE则是表示替换表中所有字段。

案例
添加列

alter table dept_partition add columns(deptdesc string);

更新列

alter table dept_partition change column deptdesc desc int;

替换列

alter table dept_partition replace columns(deptno string, dname string, loc string);

2.6.3删除表

drop table dept_partition;

注意：外部表不能简单的通过这个命令删除，这个命令只能删除外部表的元数据，没有办法删除hdfs上面的数据，如果需要将外部表彻底删除，有以下方法：

方案一：转换为内部表再删除
ALTER TABLE xxx SET TBLPROPERTIES('EXTERNAL'='False');

drop table xxx;

方案二：删除元数据，然后使用hdfs删除数据

3、DML数据操作

3.1 数据导入

3.1.1 向表中装载数据（Load）

语法
hive> load data [local] inpath '路径' [overwrite] into table 表名 [partition (partcol1=val1,…)];
1
（1）load data:表示加载数据

（2）local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表

（3）inpath:表示加载数据的路径

（4）overwrite:表示覆盖表中已有数据，否则表示追加

（5）into table:表示加载到哪张表

（6）表名:表示具体的表

（7）partition:表示上传到指定分区

3.1.2 通过查询语句向表中插入数据（Insert）

案例
基本插入

insert into table ?student partition(month='201709') values(1,'wangwu');

insert overwrite table student partition(month='201708') select id, name from student where month='201709';

多插入

from dept_partition
? ? ? ? ? ? ? insert overwrite table dept_partition partition(month='201707')
? ? ? ? ? ? ? select deptno,dname,loc where month='201709'
? ? ? ? ? ? ? insert overwrite table dept_partition partition(month='201706')
? ? ? ? ? ? ? select deptno,dname,loc ?where month='201709';

3.1.3 查询语句中创建表并加载数据（As Select）

根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student;

3.1.4 创建表时通过Location指定加载数据路径

创建表，并指定在hdfs上的位置

create table if not exists student5(
id int, name string)
row format delimited fields terminated by '\t'
location '/user/hive/warehouse/student5';

上传数据到hdfs上

dfs -put /opt/datas/student.txt /opt/hive/warehouse/student5;

3.1.5 Import数据到指定Hive表中

注意：先用export导出后，再将数据导入。

import table student2 partition(month='201709') from '/opt/hive/warehouse/export/student';

3.2 数据导出

3.2.1 Insert导出

1．将查询的结果导出到本地

insert overwrite local directory '/opt/datas' select * from dept_partition;

2．将查询的结果格式化导出到本地

insert overwrite local directory '/opt/datas/dept1'
row format delimited
fields terminated by '|'
select * from dept_partition;

3．将查询的结果导出到HDFS上(没有local)

insert overwrite directory '/opt/datas/dept'
row format delimited
fields terminated by '|'
select * from dept_partition;

3.2.2 Hadoop命令导出到本地

dfs -get /opt/hive/warehouse/employee/employee.txt /opt/datas/dept2/dept.txt;

3.2.3 Hive Shell 命令导出?

基本语法：（hive -f/-e 执行语句或者脚本 > file）

hive -e 'select * from hivetest.dept_partition;' > /opt/datas/dept3/dept.txt;

注意：需要在shell窗口执行，需要库名.表名，需要本地文件夹存在。

3.2.4 Export导出到HDFS上

export table hivetest.dept_partition to '/opt/datas/dept2';

3.3 清除表中数据（Truncate）

注意：Truncate只能删除管理表，不能删除外部表中数据

truncate table student;

文章来源:https://blog.csdn.net/liguohuaty/article/details/135391591
本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若内容造成侵权/违法违规/事实不符，请联系我的编程经验分享网邮箱：veading@qq.com进行投诉反馈，一经查实，立即删除！