Michael.W基于Foundry精读Openzeppelin第44期——ERC20Pausable.sol

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 ERC20Pausable.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/token/ERC20/extensions/ERC20Pausable.sol

ERC20Pausable库是ERC20的拓展。考虑到如下业务需求：1. 在一定时间段内禁止该token的交易；2. 当合约出现重大bug时，紧急停止一切该token的转移，该库提供了可暂停的transfer、mint及burn功能。需要注意的是：ERC20Pausable库并没有提供切换暂停状态的函数，需要开发人员自行开发——同时需要注意切换暂停状态的权限问题。

1. 目标合约

继承ERC20Pausable合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/token/ERC20/extensions/MockERC20Pausable.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/token/ERC20/extensions/ERC20Pausable.sol";

contract MockERC20Pausable is ERC20Pausable {
    constructor(string memory name, string memory symbol)
    ERC20(name, symbol)
    Pausable(){}

    function pause() external {
        _pause();
    }

    function mint(address account, uint amount) external {
        _mint(account, amount);
    }

    function burn(address account, uint amount) external {
        _burn(account, amount);
    }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/token/ERC20/extensions/ERC20Pausable.t.sol

2. 代码精读

2.1 _beforeTokenTransfer(address from, address to, uint256 amount) internal

ERC20Pausable重写ERC20._beforeTokenTransfer()方法。因为ERC20的internal方法_transfer()、_mint()和_burn()中都调用了_beforeTokenTransfer()方法，可在此处统一增添暂停限制的判断。

    // 每次进行该token的转移之前，都会检查当前合约需为非暂停状态
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual override {
    	// 调用ERC20._beforeTokenTransfer()
        super._beforeTokenTransfer(from, to, amount);
		// 要求当前合约为非暂停状态，否则revert
        require(!paused(), "ERC20Pausable: token transfer while paused");
    }

foundry代码验证：

contract ERC20PausableTest is Test {
    MockERC20Pausable private _testing = new MockERC20Pausable("test name", "test symbol");
    address private user1 = address(1);
    address private user2 = address(2);

    function test_BeforeTokenTransfer() external {
        // pass mint/burn/transfer/transferFrom if not paused
        assertFalse(_testing.paused());
        // mint
        _testing.mint(user1, 100);
        assertEq(_testing.balanceOf(user1), 100);
        // burn
        _testing.burn(user1, 1);
        assertEq(_testing.balanceOf(user1), 100 - 1);
        // transfer
        vm.prank(user1);
        _testing.transfer(user2, 2);
        assertEq(_testing.balanceOf(user1), 100 - 1 - 2);
        assertEq(_testing.balanceOf(user2), 2);
        // transferFrom
        vm.prank(user1);
        _testing.approve(address(this), 50);
        _testing.transferFrom(user1, user2, 10);
        assertEq(_testing.balanceOf(user1), 100 - 1 - 2 - 10);
        assertEq(_testing.balanceOf(user2), 2 + 10);
        assertEq(_testing.allowance(user1, address(this)), 50 - 10);

        // revert mint/burn/transfer/transferFrom if paused
        _testing.pause();
        assertTrue(_testing.paused());
        // mint
        vm.expectRevert("ERC20Pausable: token transfer while paused");
        _testing.mint(user1, 100);
        // burn
        vm.expectRevert("ERC20Pausable: token transfer while paused");
        _testing.burn(user1, 1);
        // transfer
        vm.expectRevert("ERC20Pausable: token transfer while paused");
        vm.prank(user1);
        _testing.transfer(user2, 2);
        // transfer from
        vm.expectRevert("ERC20Pausable: token transfer while paused");
        _testing.transferFrom(user1, user2, 10);
    }
}

ps:
本人热爱图灵，热爱中本聪，热爱V神。
以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。
同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！
如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人